Loading ...
Sorry, an error occurred while loading the content.

[Clip] Re: Alarm

Expand Messages
  • Jody
    Hi Bob, ... Maybe you can use one of these. They give an alram at the time you specify. Well, the simple one goes off if the time is greater than what you
    Message 1 of 2 , Nov 29, 1999
    • 0 Attachment
      Hi Bob,

      > I already use the one which counts from a setting of seconds
      > but I would like to use the fuller version, which I cannot
      > trace.

      Maybe you can use one of these. They give an alram at the time
      you specify. Well, the simple one goes off if the time is
      greater than what you put in when the check is made (set for
      every 30 secs). The other one sets back one minute and checks to
      see if it is in that range. At worst, you might be a minute
      early for work - that is if I did my calculations correct - you
      could be an hour late - haha. I'm brain dead - nite. ;) Watch
      out for the long lines...

      <--- Copy below this line --->
      H="Timer Start"
      ; Last Updated 11/29/1999, Sojourner@..., jody
      ; Watch out for the long lines

      ; Checks every 30 seconds
      ^!TimerStart 30000
      ; Which reminder
      ^!TimerPlay ^?[==Simple Alarm|Alarm 01|Alarm 02|Alarm 03]
      ^!Sound ^$GetSoundPath$MsgType.wav


      H="Timer Stop"
      ^!TimerStop
      ^!Sound ^$GetSoundPath$MsgBell.wav

      H="Set Simple Alarm"
      ^!Set %p_Time%=^$Calc(^?[HourMinuteSecond 113000 (12 hour clock)]-60)$


      H="Set Alarms"
      ; Last Updated 11/29/1999, Sojourner@..., jody
      ; Makes ini file in Library folder called NtbUsers.ini
      ; Watch out for the long lines

      ^!SetIniFile NtbUsers

      ^!SetWizardLabel Current setting: ^$GetValue("Alarm:Alarm01")$

      ; long line till blank
      ^!Info [L]Current alarm settings:^p^pAlarm 01: ^$GetValue("Alarm:Alarm01")$^pAlarm 02: ^$GetValue("Alarm:Alarm02")$^pAlarm 03: ^$GetValue("Alarm:Alarm03")$

      ; long line till blank
      ^!Set %Day%=^?{Day: Sun, Mon, Tue...=Sun|_Mon|Tue|Wed|Thu|Fri|Sat}; %Hour%=^?{Hour (12 hour clock, do not add leading zero)=2}; %Min%=^?{Minute}; %Sec%=^?{Second=_00|^=}; %aNum%=^?{Set Alarm==01|02|03}

      ^!Set %Min%=^$Calc(^%Min%-1)$
      ^!If ^%Min% = -1 Next else Skip
      ^!Set %Hour%=^$Calc(^%Hour%-1)$; %Min%=59
      ^!If ^%Min% = 0 Next else Skip
      ^!Set %Min%=00
      ^!If ^%Hour% = 0 Next else Skip
      ^!Set %Hour%=12

      ^!SaveValue Alarm:Alarm^%aNum%=^%Day%-^%Hour%:^%Min%:^%Sec%a/p


      H="Alarm"
      ^!Sound ^$GetSoundPath$bonktrip.wav
      ^!Info It's time!^p^$GetDate(dddd "the" dd "of" mmmm hh:nn:ss ampm)$


      H=";"


      H="_Simple Alarm"
      ^!If ^$GetDate(hhnnss)$ => ^%p_Time% Next else Skip_2
      ^!Clip "Alarm"


      H="_Alarm 01"
      ; long line till ^!Clip
      ^!IfInDateRange ddd-hh:n:ssa/p ^$GetValue("Alarm:Alarm01")$..ddd-hh:n:ssa/p Next else Skip_2
      ^!Clip "Alarm"


      H="_Alarm 02"
      ; long line till ^!Clip
      ^!IfInDateRange ddd-hh:n:ssa/p ^$GetValue("Alarm:Alarm02")$..ddd-hh:n:ssa/p Next else Skip_2
      ^!Clip "Alarm"


      H="_Alarm 03"
      ; long line till ^!Clip
      ^!IfInDateRange ddd-hh:n:ssa/p ^$GetValue("Alarm:Alarm03")$..ddd-hh:n:ssa/p Next else Skip_2
      ^!Clip "Alarm"


      H="_OnOpen"
      ^!Clip "Timer Start"

      <--- Copy above this line, right --->
      <--- click over the Clipbook and --->
      <--- choose "Add from Clipboard" --->

      nite...


      Happy Clip'n!
      Jody

      http://www.sureword.com/notetab

      The NoteTab Clip List...
      mailto:Ntb-Clips-Subscribe@...
      mailto:Ntb-Clips-UnSubscribe@...
    Your message has been successfully submitted and would be delivered to recipients shortly.